Subversion Repositories wimsdev

!if $save!=$empty

  !if $jquery_defined=no

    d=!char 2,3 of $[100+abs(floor($dayup_expiration))]

    m=!char 2,3 of $[100+abs(floor($monthup_expiration))]

    y=!char 1 to 4 of $[abs(floor($yearup_expiration))]

    up_expiration=$(y)$(m)$(d)

  !endif

  !! ---------- testind condition on expire date for compatibility sharable/sharing

  !! cannot have expiration date before a sharable classe

  !! cannot have expiration date after a sharing classe

  test=!defof sharable_all\

sharing_all in wimshome/log/classes/$wims_class/neighbors

  !distribute line $test into sharable,sharing

  !distribute item 0,99999999 into expmin,expmax

  !for cl in $sharable

    test=!defof class_expiration in wimshome/log/classes/$cl/.def

    expmin=$[max($test,$expmin)]

  !next cl

  !if $up_expiration<$expmin

    error=expdate_sharable $expmin

    !exit

  !endif

  !for cl in $sharing

    test=!defof class_expiration in wimshome/log/classes/$cl/.def

    expmax=$[min($test,$expmax)]

  !next cl

  !if $up_expiration>$expmax

    error=expdate_sharing $expmax

    !exit

  !endif

  !! ---------- end sharing/sharable test

  !read scripts/setdef.proc

  !if $up_exotitleform!=$class_exotitleform

  !! change value of wims_exotitleform for connected student

    !readproc adm/whoconnect 1

    !for k=1 to $wims_numpartconnected

      !let s=!itemcnt $(wims_whoconnect[$k])

      !for ses=3 to $s

        !setdef wims_exotitleform=$up_exotitleform in wimshome/sessions/$(wims_whoconnect[$k;$ses])/var.stat

      !next ses

    !next se

    !setdef wims_exotitleform=$up_exotitleform in wimshome/sessions/$wims_session/var.stat

  !endif

  !defread wimshome/log/classes/$wims_class/.def

  wims_class_log=Modify class configuration by $wims_realuser

!endif

!!read adm/du $wims_home/log/classes/$wims_class

!if $wims_superclass!=$empty

  supertype=!defof class_type in wimshome/log/classes/$wims_superclass/.def

  class_expiration=!defof class_expiration in wimshome/log/classes/$wims_superclass/.def

  classdepth=!translate internal / to , in $wims_class

  classdepth=!itemcnt $classdepth

!endif