Subversion Repositories wimsdev

!! display freework page for student type=1 or type=2

!if $emptypage=yes

  !exit

!endif

<div class="wims_sheet_desc">$desc</div>

<div class="wims_widget_box medium_size">

  <div class="title_box">

      <h2 class="wims_title">$(name_subject)</h2>

  </div>

  <div class="box_content">

    !read proc/listfile.phtml subject 0

  </div>

</div>

!if $activetest=1

  <div class="wims_widget_box medium_size">

    <div class="title_box">

      <h2 class="wims_title">$(name_copie)</h2>

    </div>

  <div class="box_content">

    !if $type=1

      !if $activetest>=2

        $name_copie_toolate2

      !else

        !if $toolate=yes

          $name_copie_toolate

        !else

          $name_copie_type1

        !endif

        !read adm/date.phtml $deadline

        $l_date_out

        $wims_name_at

        !replace internal : by H in $(timedeadline).

      !endif

    !else

      !! ---   type=2

      !if $activetest>=2

        $name_copie_toolate2

      !else

        !if $toolate=yes

          <div class="field box fullwidth">

            $name_copie_toolate

            !read adm/date.phtml $deadline

            $l_date_out $wims_name_at

            !replace internal : by H in $(timedeadline).

          </div>

        !else

          <div class="field box fullwidth">

            $name_copie_type2

            !read adm/date.phtml $deadline

            $l_date_out $wims_name_at

            !replace internal : by H in $(timedeadline).

            !if $seealltime=1

              <div>$name_warningseealltime</div>

            !endif

          </div>

        !endif

        !if $data_0!=$empty

            <div class="field box fullwidth">

              $name_oldwork

              !getfile freeworksdata/work$freework-$(data_0[2]) $(data_0[2])

              $name_the

              !read adm/date.phtml $(data_0[3])

              $l_date_out $wims_name_at

              !replace internal : by H in $(data_0[4]).

            </div>

        !endif

        !if $toolate=$empty

          <div class="field box fullwidth">

            !! --- interface de chargement de fichier

            !if $quota_free>=1

              <fieldset class="property_fields blockcenter">

                !set wims_form_method=file

                !form reply

                  <input type="hidden" name="job" value="student1" />

                  <input type="hidden" name="freework" value="$freework" />

                  <label for="wims_deposit">$name_depos</label>

                  <input type="file" size="35" name="wims_deposit" id="wims_deposit" />

                  <div class="formHelp">$name_copie_type2bis.

                    !if $data_0!=$empty

                      $name_msgstudenthavefile

                    !endif

                  </div>

                  !if $wims_user=supervisor

                    <input type="submit" value="$wims_name_submit" disabled/>

                  !else

                    <input type="submit" value="$wims_name_submit" />

                  !endif

                !formend

              </fieldset>

            !else

              $name_warning_fullclass

            !endif

          </div>

        !endif

      !endif

    !endif

  </div></div>

!endif

!if $codownload=1 or $activetest>=2

  <div class="wims_widget_box medium_size">

    <div class="title_box">

      <h2 class="wims_title">$(name_correctedwork)</h2>

    </div>

    <div class="box_content">

      <div class="field box">

        !if $codownload=1

          !if $(data_0[5])!=$empty

            !getfile freeworksdata/workco$freework-$(data_0[5]) $(data_0[5])

          !else

            $name_nouploaded

          !endif

        !else

            $(name_nomorecodownload).

        !endif

      </div>

      !if $scoring>0

        <div class="field box">

          !let k_=!positionof item $wims_user in $uulist

          !if $k_!=$empty

            !let t_=!record $[$k_+1] of wimshome/log/classes/$wims_class/.grades

            !let t_=!item $[$scoring+2] of $t_

          !else

            !let t_=$empty

          !endif

          <strong>$(name_score)</strong>

          !if $t_!=$empty

            $t_/$maxscore

          !else

            $name_noscore

          !endif

        </div>

      !endif

    </div>

  </div>

!endif

!if $flistsolution!=$empty

  <div class="wims_widget_box medium_size">

    <div class="title_box">

      <h2 class="wims_title">$(name_solution)</h2>

    </div>

    <div class="box_content">

      !if $displaysolution=1

        !read proc/listfile.phtml solution 0

      !else

        $name_solutiondate

        !read adm/date.phtml $soldate

        $l_date_out

        $wims_name_at

        !replace internal : by H in $(timesoldate).

      !endif

    </div>

  </div>

!endif

!if $activetest>1 and $type>=2

  $name_userperimemessage

!endif