Subversion Repositories wimsdev

!set form_titlename=$wims_name_title

!set form_caption=$name_programproperties

!set title=$class_description

!set sup=$class_Supervisor

<div id="widget_zone_list">

!if $jquery_defined=yes

  !read adm/tabscript zone_list

!endif

<ul>

 <li><a href="#wims_classform">$wims_name_properties</a></li>

 <li><a href="#wims_zone_course">$wims_name_course</a></li>

 <li><a href="#wims_zone_icourse">$wims_name_icourse</a></li>

 <li><a href="#wims_zone_recsharable">$name_prog6</a></li>

 <li><a href="#wims_othergestion">$name_othergestion</a></li>

</ul>

<div id="wims_classform">

!read scripts/progform.phtml

!if $hastest=yes

 $name_prog1

  $

 !set wims_ref_class=wims_button_help

 !href cmd=help&special_parm=structure#test $wims_name_help

 !set wims_ref_class=wims_button

 !href module=adm/class/classes&type=authsupervisor&class=$wims_superclass/$prog/0 $name_visit

 $

 !set wims_ref_class=wims_button wims_warning

 !href cmd=reply&job=deltest $wims_name_erase

!else

 $name_prog2

 !href cmd=reply&job=addtest $name_prog3

 $

 !set wims_ref_class=wims_button_help

 !href cmd=help&special_parm=structure#test $wims_name_help

!endif

</div>

<div id="wims_zone_course">

!if $coursecnt=0

 $name_prog4

 !href cmd=reply&cparent=prog&job=addcourse $wims_name_addcourse

 $

!set wims_ref_class=wims_button_help

 !href cmd=help&special_parm=structure#course $wims_name_help

  $

!else

 $table_header

 <caption>$name_prog5

 $

!set wims_ref_class=wims_button_help

 !href cmd=help&special_parm=structure#course $wims_name_help

 $

 !href cmd=reply&cparent=prog&job=addcourse $wims_name_addcourse

 </caption>

 $table_hdtr

 <th>$name_code</th><th>$wims_name_name</th><th>$wims_name_action</th><th>$name_supervisor2</th>

 <th class="small">$name_participant</th>

 </tr>

 !for i=1 to $coursecnt

   !set l=!line $i of $courses

   !distribute items $l into l_,s_,t_,n_

   $table_tr<td>$l_</td>

   <td>

   !href cmd=reply&job=course&cparent=prog&course=$l_ $t_

   </td><td>

   !set wims_ref_class=wims_button wims_warning

    !href cmd=reply&job=delcourse&cparent=prog&del=$l_ $wims_name_erase

   </td><td>

   !if $s_!=$empty

    !if $s_=supervisor

     $wims_name_supervisor

    !else

     !default n_=$s_

     !href cmd=reply&job=modteacher&teacher=$s_ $n_

    !endif

   !else

    $name_nonavailable

   !endif

   !set c=!recordcnt $classdir1/$l_/.userlist

   </td><td>$c</td>

   </tr>

 !next i

 $table_end

!endif

</div>

<div id="wims_zone_icourse">

!if $icoursecnt=0

$name_prog9

 !href cmd=reply&cparent=prog&job=addicourse $wims_name_addicourse

 $

!set wims_ref_class=wims_button_help

 !href cmd=help&special_parm=structure#icourse $wims_name_help

!else

 $table_header

 <caption>$wims_name_icourse

  $

!set wims_ref_class=wims_button_help

 !href cmd=help&special_parm=structure#icourse $wims_name_help

  $

 !href cmd=reply&cparent=prog&job=addicourse $wims_name_addcourse

 </caption>

 $table_hdtr

 <th>$name_code</th><th>$wims_name_name</th><th>$wims_name_action</th><th>$name_supervisor2</th>

 <th class="small">$name_participant</th>

 </tr>

 !for i=1 to $icoursecnt

   !set l=!line $i of $icourses

   !distribute items $l into l_,s_,t_,n_

   $table_tr<td>$l_</td>

   <td>

   !href cmd=reply&job=icourse&cparent=prog&course=$l_ $t_

   </td><td>

   !set wims_ref_class=wims_button wims_warning

    !href cmd=reply&job=delcourse&cparent=prog&del=$l_ $wims_name_erase

   </td><td>

   !if $s_!=$empty

    !if $s_=supervisor

     $s_

    !else

     !default n_=$s_

     !href cmd=reply&job=modteacher&teacher=$s_ $n_

    !endif

   !else

    $name_nonavailable

   !endif

   !set c=!recordcnt $classdir1/$l_/.userlist

   </td><td>$c</td>

 !next i

  </tr>

 $table_end

!endif

</div>

<div id="wims_zone_recsharable">

!if $recsharable!=$empty

 $table_header

 <caption>$name_prog6</caption>

 $table_hdtr

 <th>Code</th>

 <th>$wims_name_level</th>

 <th>$wims_name_program</th>

 </tr>

 !set n=!linecnt $recsharable

 !for i=1 to $n

  $table_tr

  !set l=!line $i of $recsharable

  !distribute items $l into add,name

  !set l_=!translate / to , in $add

  !set l_=!item 1 of $l_

  !set l_=!defof class_description in $classdir1/$l_/.def

  <td><span class="tt">$add</span></td>

  <td>$l_</td>

  <td style="text-align:left">

  !href cmd=reply&job=progshare&prog=$prog&shareprog=$add $name

  </td></tr>

 !next i

 $table_end

!endif

!if $class_recshare!=$empty

 <p>

 !if $class_recshare=main

  $name_prog7

 !else

  !set l_=!translate / to , in $class_recshare

  !set shareprog=!defof class_description in $classdir1/$class_recshare/.def

  !set sharelevel=!defof class_description in $classdir1/$(l_[1])/.def

  $name_prog8

  <em>$shareprog</em> ($name_level <em>$sharelevel</em>).

 !endif

 </p>

!endif

</div>

!set wims_menu_items=!append line addcourse,1,cmd=reply&cparent=prog&job=addcourse\

addicourse,1,cmd=reply&cparent=prog&job=addicourse\

to $wims_menu_items

!reset title