Subversion Repositories wimsdev

!read adm/css.phtml

!read lang/names.phtml.$moduclass_lang

!read adm/class/classname.phtml $wims_classname\

$wims_institutionname

!set js=!record 0 of js/chooselist.js

!set wims_html_header=!append line $js to $wims_html_header

!header1

!read adm/title.phtml 1\

$classname\

$module_title\

($supervisormail)

!set wims_menu_items=!append line part_list,1,module=adm/class/userlist\

 to $wims_menu_items

!if $error!=$empty

  !read msg.phtml

  !set job=

!endif

!if $cmd!=reply or $error!=$empty

$name_intro

 !form reply

 <center><table>

 <tr>

  <td>$name_subject</td>

  <td><input name="subject" size="45" value="$subject"/></td>

</tr>

<tr>

<td>$name_message</td>

 <td><textarea name="msg" cols="40" rows="5">$msg</textarea></td>

 </tr></table>

<input type="submit" name="reg" value="$wims_name_send"/></center>

<p>

<fieldset><legend>$name_menu

</legend>

!set file=wimshome/log/classes/$wims_class/.userlist

!set cnt=!recordcnt wimshome/log/classes/$wims_class/.userlist

!for lu =1 to $cnt

  !set us_=!record $lu of $file

  !if $(us_[3]) notitemof $select_user

   !set option=!append line <option value="$(us_[3])">$(us_[1]) $(us_[2]) ($(us_[3]))</option> to $option

  !else

   !set option_select=!append line <option value="$(us_[3])">$(us_[1]) $(us_[2]) ($(us_[3]))</option> to $option_select

  !endif

!next

!if $option=$empty

  !set option=<option value=""></option>

!endif

!if $option_select=$empty

  !set option_select=<option value=""></option>

!endif

$name_expert0

 

!set wims_ref_class=wims_button_help

!href cmd=help&special_parm=general $wims_name_help

<p>

!formradio job list all prompt $name_allparticipants

</p>

!formradio job list select prompt <b>$name_select</b>:

$name_expert1

!set wims_chooselist_select=$option

!set wims_chooselist_checked=$option_select

<center>

!read js/chooselist.phtml select_user1,select_user2,select_user

</center>

<p></p>

!formradio job list s prompt <b>$name_loginlist</b>:

$name_expert2

 <center>

   <textarea name="loginlist" cols="20" rows="5">$loginlist</textarea>

</center>

!default job=$job

<p>

!formradio job list filter prompt <b>$name_filter:</b>

$name_expert3

 

!set wims_ref_class=wims_button_help

!href cmd=help&special_parm=filter $wims_name_help

 <center><textarea name="variable" cols="20" rows="3">$variable</textarea>

</center>

</fieldset>

</form>

!goto end

!endif

!if $confirm=$empty and $reg!=

 !if $email_exists=0

!! $list_user$list_noemail

  !if $list_user$list_noemail notsametext

  $name_noemail

  ($wims_name_Login : $(list_noemail[3]))

  !else

   $name_nouser

  !endif

  <p>

  !set wims_menu_items=!append line back2,1,cmd=resume\

 to $wims_menu_items

  !goto end

 !endif

$name_warning

<center>

<input name="subject" size="45" value="$subject" readonly/>

<br>

<textarea cols="40" rows="5" readonly>

$msg

</textarea>

</center>

<pre>

$list_user

</pre>

<pre>

$list_teacher

</pre>

<p>

!if $list_noemail notsametext

$name_noemail2

<pre>

$list_noemail

</pre>

!endif

 !form reply

<center>

!set wims_ref_class=wims_button

!href cmd=reply&confirm=yes $wims_name_send

   

!set wims_ref_class=wims_button

!href cmd=resume $wims_name_giveup

</center>

</form>

!endif

 !set wims_menu_items=!append line back2,1,cmd=resume\

 to $wims_menu_items

!endif

!if $confirm=yes

 !set cmp=0

 !set cmp_tr=0

 !set cnt=!linecnt $list_user

 !for l_ =1 to $cnt

  !set u=!line $l_ of $list_user

  !if $(u[4])!=

   !mailto $(u[4]) -- -f $supervisormail\

   [WIMS $wims_classname] $subject\

 $msg\

 \

   !endif

  !reset u

 !next

 !set cnt=!linecnt $list_teacher

 !for l_ =1 to $cnt

  !set u=!line $l_ of $list_teacher

  !if $(u[4])!=

   !mailto $(u[4]) -- -f $supervisormail\

   [WIMS $wims_classname] $subject\

 $msg\

 \

   !endif

  !reset u

 !next

!endif

!if $cmd=reply and $confirm=yes

<p>

$name_participant1

<pre>$(list_user[;1..2])</pre>

!if $list_noemail notsametext

$name_participant2

<pre>

$(list_noemail[;1..2])

</pre>

!endif

!set wims_module_log=class $class: sendmail

!set date=!translate : to . in $wims_now

!appendfile wimshome/log/classes/$wims_class/.log $date $httpd_REMOTE_ADDR      $supervisormail send mail to $(list_user[;1]) $(list_teacher[;1])

 !reset list_user list_noemail

!endif

:end

!reset confirm reg abandon error

!tail