Subversion Repositories wimsdev

!!!###language independant

!read adm/title.phtml 1\

$classname\

$name_workdetail

<center><b>

!if $wims_user=supervisor

 !href cmd=reply&job=userprop&getuser=$getuser $name_student1

 !if $getuser isitemof $wims_connectedlogin

  <img src="gifs/themes/$wims_theme_icon/connected.png" width="15px"/>

 !endif

!else

 $name_student1

!endif

</b><br/><font size="-1">$wims_name_Login: <tt>$getuser</tt>

!if $user_external_auth!=$empty

(<tt>$user_external_auth</tt>)

!endif

!if $user_email!=$empty

<br/>

$wims_name_email: <a href="mailto:$user_email">$user_email</a>

!endif

</font>

</center>

  !if $user_photourl!=

   <img src="$user_photourl" width="100px" style="position:absolute;top:50px;right:5%;" alt="$name_student2" />

  !endif

!if $eremain>0

 <div class="emptyline">&nbsp;</div>

 $name_activesession:

 !href cmd=reply&job=userexam&getuser=$getuser $esession

!else

 !if $wims_user=supervisor and $wims_supertype iswordof 2 4

  !readproc adm/gateway/transfer $getuser test

  !if $transfer_test>0

   !href cmd=reply&job=transfer&getuser=$getuser $name_transfert

  !endif

 !endif

!endif

 <div class="emptyline">&nbsp;</div>

!if $manual>0 and $gcnt>0 and $teacher!=$empty

 $table_header

 <caption><small>

 $name_minmax:

 $min_glob/$mean_glob/$max_glob</small></caption>

 $table_hdtr<th>$wims_name_name<th>$(name_thsheet[6])<th>$(name_thsheet[7])</th></tr>

 $table_hdtr<td>$name_manualscore</td>

     <td align="center">$manual%</td>

     !read adm/class/colors $[ceil(10*$mav/$scoremax)]

     <td style=$style_note>$mav</td></tr>

 $table_hdtr<td>$name_autoscore

     <td align="center">$[100-$manual]%</td>

     !read adm/class/colors $[ceil(10*$per/$scoremax)]

     <td style=$style_note>$per</td></tr>

 $table_tr<td><b>$name_globalaverage</b> (/ $scoremax)</td>

     <td align="center">100%</td>

     !read adm/class/colors $[ceil(10*$globalav/$scoremax)]

     <td style=$style_note>$globalav</td></tr>

 $table_end

 $table_header$table_hdtr<th colspan="3">$name_manualscore

 !if $wims_user=supervisor

  <br/>

  !href lang=$lang&module=adm/class/grades&method=user&un=$getuser $wims_name_change

 !endif

 </th></tr>

 $table_hdtr<th>$(name_thsheet[2])<th>$(name_thsheet[4])<th>$(name_thsheet[9])</th></tr>

 !set v_=0

 !for i=1 to $gcnt

  $table_tr<td>$(titles[2+$i])<td align="center">$(w$i)</td>

  !read adm/class/colors $[10*ceil($(g_$i))/$scoremax]

  <td style=$style_note>$(g_$i)</td></tr>

 !next i

 $table_hdtr<td colspan="2">$name_Average</td>

 !read adm/class/colors $[ceil(10*$mav/$scoremax)]

 <td style=$style_note>$mav</td></tr>

 $table_end

!else

 <center>

 $name_globalaverage: <b>$per</b> / $scoremax.

 !if $min_glob<$scoremax

  <br/><small>$name_minmax:

  $min_glob/$mean_glob/$max_glob</small>

 !endif

 </center>

 <div class="emptyline">&nbsp;</div>

!endif

!!readdef wimshome/log/classes/$wims_class/.def

!!default class_topscores=0

!if $class_topscores>0

 $table_header$table_hdtr<th colspan="2">$name_topten</td></tr>

 !for i=1 to $class_topscores

  !set L=!line $i of   $TT

  !if $class_anonymtopscores=yes

   !set name=$i

  !else

   !set name=!item 1 of $L

   !set firstname=!item 2 of $L

   !set name=$name $firstname

  !endif

  !set avg=!item 4 of $L

$table_tr<td align="right"><b><small>$name &nbsp;</small></b><td align="left"><small>&nbsp;$avg</small></td></tr>

 !next i

 $table_end

!endif

!if $eactivecnt>0

 $table_header$table_hdtr<th colspan="4">$name_examnote

 !if $wims_user=supervisor or $class_examshow!=no

  <small>

  !href cmd=reply&job=examcheck&checkuser=$getuser [$wims_name_detail]

  </small>

 !endif

 </th></tr>

 $table_hdtr<th>$(name_thsheet[1])</th><th>$(name_thsheet[2])</th><th>$(name_thsheet[9])/$scoremax

 </th></tr>

 !for i in $activexams

  !set l=!record $i of wimshome/log/classes/$wims_class/exams/.exams

  !set t=!line 4 of $l

  $table_tr<td align="center">$i</td>

  <td align="center">$t</td>

  !if $[rint(10*$(es_$i)*$scoremax)/100]>0

   !read adm/class/color $[ceil($(es_$i))]

   <td style=$style_note>$[rint(10*$(es_$i)*$scoremax)/100]</td>

  !else

   <td align="center">--</td>

  !endif

  </tr>

 !next i

 $table_end

!endif

!for i=1 to $activecnt

 !set l_=!line $i of $activesheets

 !distribute items $l_ into n_,e_

 !set L_=!line $n_ of $defaultformula

 !distribute word $L_ into A_,B_

 !default A_=1

 !default B_=2

 !set t_=!item 3 to -1 of $l_

 !set t_=!char 1 to $title_limit of $t_

 !set v_=!getscorerequire sheet=$n_ user=$getuser

 !set w_=!wordcnt $v_

 !set S_=0

 !for k=1 to $w_

  !set a_=!word $k of $v_

  !set S_=$[$S_+$a_]

 !next k

 !if $S_<=0

  !goto next

 !endif

 !set seq_open=!defof sequence_open in wimshome/log/classes/$wims_class/seq/.def

 !if $seq_open!=yes

   !set hat=$name_Sheet $n_ : $t_

 !else

  !set hat=$wims_name_sequence $(t_[1]) : $(t_[2..-1])

 !endif

 <a id="sheet$n_"></a>

 <div class="emptyline">&nbsp;</div>

 $table_header$table_hdtr<th colspan="7">

 !href module=adm/sheet&sh=$n_ $hat

 <small>$(name_thsheet[4]) $A_, $(name_thsheet[8]) $B_<br/>

 !set A_=!line $n_ of $percents

 !distribute words $A_ into p1,p2

 !if $p2!=$empty

  !distribute item $[$p1/100],$[$p2/10] into x_,y_

  !set p_=$[rint(100*$scoremax*$(f_$i))/100]

  $name_done:$p1% , $(name_thsheet[7])  $p2/10, $name_equiv <b>$p_</b> / $scoremax.

  !if $(min_$i)<$scoremax

   <br/>$name_minmax: $(min_$i)/$(mean_$i)/$(max_$i)

  !endif

 !endif

 </small>

 $table_hdtr<th>$(name_thsheet[1])<th>$(name_thsheet[2])</th><th>$(name_thsheet[3])</th><th>$(name_thsheet[4])

     <th>$(name_thsheet[5])</th><th>$(name_thsheet[6])</th><th>$(name_thsheet[7])</th></tr>

 !for j=1 to $e_

  !let d=!record $j of wimshome/log/classes/$wims_class/sheets/.sheet$n_

  !distribute line $d into t,t,req_,weight_,title_,t

  $table_tr<td align="center">$j</td>

  <td>$(title_)</td>

  <td align="center">$(req_)</td>

  <td align="center">$(weight_)</td>

  !set d_=!getscore user=$getuser sheet=$n_ work=$j

  !default d_=0

  !read adm/class/colors $[ceil(10*$d_/$(req_))]

  !if $d_>0

   <td style=$style_note>

   $d_

  !else

   <td align="center">--

  !endif

  </td>

  !if $(req_)>0

   !read adm/class/colors $[ceil(10*$d_/$(req_))]

   !if $d_>0

    <td align="right" style=$style_note>

    $[round(100*$d_/$(req_))]%

   !else

    <td align="center">--

   !endif

  !else

   <td align="center">---

  !endif

  </td>

  !set d_=!getscoremean user=$getuser sheet=$n_ work=$j

  !default d_=0

  !read adm/class/colors $[ceil($d_)]

  !if $d_>0

   <td style=$style_note>

       $d_

  !else

   <td align="center">--

  !endif

   </td>

   </tr>

 !next j

 $table_end

 :next

!next i

!if $exologs!=$empty

 !set wims_menu_items=!append line reg_ex,1,module=adm/class/exolog&cmd=new&job=list&checkuser=$getuser\

 to $wims_menu_items

!endif

!if $wims_user=supervisor

 !set wims_menu_items=!append line rawdata,1,cmd=reply&job=getraw&getraw=$getuser\

 delprep,1,cmd=reply&job=delprep&delprep=$getuser\

passwd,1,module=adm/class/passwd&job=part&part=$getuser\

part_list,1,cmd=resume\

to $wims_menu_items

 !if (($wims_supertype<3 and $wims_typename=class) or ($wims_supertype=4 and $wims_typename=course)) and $wims_showlivret!=no

  !set wims_menu_items=!append line livret,1,module=adm/class/livret&job=user&user=$getuser to $wims_menu_items

 !endif

!else

 !if $wims_showlivret!=no

  !set livret_nbcomp=!recordcnt wimshome/log/classes/$wims_class/livret/.comps

  !if $livret_nbcomp >0

   !set wims_menu_items=!append line livret,1,module=adm/class/livret to $wims_menu_items

  !endif

 !endif

!endif

 <div class="emptyline">&nbsp;</div>