Subversion Repositories wimsdev

!! create a datepicker form with some option (in line) in wims_read_parm

!!line 1 : default value

!!line 2 : name form

!!line 3 : minDate,maxDate (use datepicker format)

!!

!!

!!

!distribute line $wims_read_parm into default_,name_,date_

!distribute item $date_ into mdate_,Mdate_

!if $jquery_defined=yes

  !set option_=dateFormat:"yymmdd"

  !if $mdate_!=$empty

    !set option_=$option_,minDate:$mdate_

  !endif

  !if $Mdate_!=$empty

    !set option_=$option_,maxDate:$Mdate_

  !endif

  !set name_=!nospace $name_

  !set js_lang=$lang

  !if $lang=cn

    !set js_lang=zh-CN

  !endif

  !if $lang=tw

    !set js_lang=zh-TW

  !endif

  !if $lang=si

    !set js_lang=sl

  !endif

  !if $lang=en

    !set js_lang=en-GB

  !endif

  <script charset="UTF-8" src="scripts/js/external/jquery-ui/ui/i18n/datepicker-$js_lang.js"></script>

  <script>

   $$( function() {$$( "#$name_" ).datepicker({$option_});});

  </script>

  <input type="text" size="10"  name="$name_" id="$name_" value="$default_" />

!else

  !if $months=$empty

    !readproc adm/lang/date.phtml.$lang

  !endif

  !set $(name_)year=!char 1 to 4 of $default_

  !set $(name_)month=!char 5 to 6 of $default_

  !set $(name_)month=$[$($(name_)month)]

  !set $(name_)day=!char 7 to 8 of $default_

  !set $(name_)day=$[$($(name_)day)]

  !set min_=!char 2 to 5 of $(date_[1])

  !set max_=!char 2 to 5 of $(date_[2])

  !formselect $(name_)day from 1 to 31

  !formselect $(name_)month from 1 to 12 prompt $months

  !formselect $(name_)year from $min_ to $max_

!endif