Subversion Repositories wimsdev

!! create a datepicker form with some option (in line) in wims_read_parm

!!line 1 : default value

!!line 2 : name form

!!line 3 : minDate,maxDate (use datepicker format)

!!

!! example call :

!! !read adm/datepickerform.phtml $expirydate\

!! expirydate\

!! "-1d","+1y"

!distribute line $wims_read_parm into default_,name_,date_

!distribute item $date_ into mdate_,Mdate_

!if $module notitemof adm/class/cdt,adm/class/regclass,adm/class/config,adm/class/exam,adm/class/sheet,adm/class/freework,adm/class/sequence,adm/vote

  !goto oldversion

!endif

!reset option_ y_ m_ d_

!if $mdate_!=$empty

  !set y_=!char 1 to 4 of $mdate_

  !set m_=!char 5 to 6 of $mdate_

  !set d_=!char 7 to 8 of $mdate_

  !set option_=$option_ min="$y_-$m_-$d_"

  !reset y_ m_ d_

!endif

!if $Mdate_!=$empty

  !set y_=!char 1 to 4 of $Mdate_

  !set m_=!char 5 to 6 of $Mdate_

  !set d_=!char 7 to 8 of $Mdate_

  !set option_=$option_ max="$y_-$m_-$d_"

  !reset y_ m_ d_

!endif

!if $default_!=$empty

  !set y_=!char 1 to 4 of $default_

  !set m_=!char 5 to 6 of $default_

  !set d_=!char 7 to 8 of $default_

  !set option_=$option_ value="$y_-$m_-$d_"

!endif

<input type="date" name="$name_" id="$name_" $option_>

!exit

:oldversion

!if $jquery_defined=yes

  !set option_=dateFormat:"yymmdd"

  !if $mdate_!=$empty

    !set option_=$option_,minDate:$mdate_

  !endif

  !if $Mdate_!=$empty

    !set option_=$option_,maxDate:$Mdate_

  !endif

  !set name_=!nospace $name_

  !set js_lang=$lang

  !if $lang=cn

    !set js_lang=zh-CN

  !endif

  !if $lang=tw

    !set js_lang=zh-TW

  !endif

  !if $lang=si

    !set js_lang=sl

  !endif

  !if $lang=en

    !set js_lang=en-GB

  !endif

  <script charset="UTF-8" src="scripts/js/external/jquery-ui/ui/i18n/datepicker-$js_lang.js"></script>

  <input type="text" name="$name_" id="$name_" value="$default_">

  <script>

    jQuery(function($$) {$$( "#$name_" ).datepicker({$option_});});

  </script>

!else

  !if $months=$empty

    !read adm/class/classlang adm/lang/date.phtml

  !endif

  !set year$(name_)=!char 1 to 4 of $default_

  !set month$(name_)=!char 5 to 6 of $default_

  !set month$(name_)=$[$(month$(name_))]

  !set day$(name_)=!char 7 to 8 of $default_

  !set day$(name_)=$[$(day$(name_))]

  !set creyear=!char 2 to 5 of $(date_[1])

  !set expyear=!char 2 to 5 of $(date_[2])

  !read adm/lang/datemenu.phtml.$moduclass_lang 1,day$(name_),month$(name_),year$(name_)

!endif