Subversion Repositories wimsdev

!set anstype=yes

!set anstyle=symtext

!set ans_reaccent=yes

!set ans_require=

!if $wims_read_parm=def

  !exit

!endif

!if debug iswordof $m_oefenv and ?analyze notin $(replygood$i)

  !set replydefaulted=yes

  !if $oef_default=yes

   !set r_=!row 1 of $(replygood$i)

   !set r_=!translate | to $\

$ in $r_

    !default reply$i=!line 1 of $r_

  !endif

!endif

!if $wims_read_parm!=noprompt

  <tr><td><label for="reply$i">$(replyname$i)</label></td><td>

!endif

!set keyboard=!getopt keyboard in $(replyoption$i)

!set style=!getopt style in $(replyoption$i)

!set style=!replace internal $ $ by ; in $style

!set style=!replace internal @ by $ $ in $style

!set inputoption=!replace internal $	$ by $\

$ in $inputsize

!set inputsize=!line 1 of $inputoption

!set inputoption=!line 2 to -1 of $inputoption

!set option=!line 1 of $inputoption

!if $option issametext default

  !set option=class="wims_oef_input"

  !set inputoption=!line 2 to -1 of $inputoption

!endif

!if $inputoption!=

  !set inputoption=$option $inputoption

!else

  !default inputoption=$option style="font-size:18px;background-color:#e8ffff;border:1px solid #3333CC;"

!endif

!default style=color:black;border:1px solid grey;margin:1px;background-color:lightgrey;font-weight:bolder;font-size:100%

!set inputsize=!translate x to , in $inputsize

!set inputsize=!items2words $inputsize

!distribute words $inputsize into sizeh,sizev

!bound sizeh between integer 10 and 60 default 20

!bound sizev between integer 1 and 20 default 1

!if universal isin $keyboard

  !set key_lang=!replace internal _ by , in $keyboard

  !set key_lang=!item 2 of $key_lang

  !reset wims_html_header

  !read js/keyboard.phtml $key_lang

  $wims_html_header

  !goto universal

!endif

!if $keyboard=si

  !set keyboard=Á Ą Ä É Ę Ě Í\

á ą ä é ę ě í\

Ó ô ú Ů Ý Č\

ó Ô Ú ů ý č\

ď Ĺ Ň Ŕ Ř Š Ž\

ť ĺ ň ŕ ř š\

  !goto kb

!endif

!if $keyboard=es

  !set keyboard=Á É Í Ñ Ó Ú Ü ¿\

á é í ñ ó ú ü ¡

  !goto kb

!endif

!if $keyboard=ru

  !set keyboard=А а Б б В в Г г Д д \

Е е Ё ё Ж ж З з И и\

Й й К к Л л М м Н н\

О о П п Р р С с Т т\

У у Ф ф Х х Ц ц\

Ч ч Ш ш Щ щ Ъ ъ \

Ы ы Ь ь Э э Ю ю Я я

  !goto kb

!endif

!if $keyboard=de

  !set keyboard= Ä ä É é Ö ö Ü ü ß

  !goto kb

!endif

!if $keyboard=el

 !set keyboard= Α Β Γ Δ Ε Ζ Η Θ Ι Κ\

 α β γ δ ε ζ η θ ι κ\

Λ Μ Ν Ξ Ο π ρ  Σ \

λ μ ν ξ ο Ρ σ Τ\

τ Υ υ Φ φ Χ χ Ψ ψ Ω ω

!!Π Π τ\

!endif

!if $keyboard=pl

  !set keyboard=Ą Ę Ó Ć Ł Ń Ś Ź Ż \

  ą ę ó ć ł ń ś ź ż

  !goto kb

!endif

!if $keyboard=it

  !set keyboard=À Á È É Ì Í Ò Ó Ù Ú\

 à á è é ì í ò ó ù ú

  !goto kb

!endif

!if $keyboard=en_ipa

  !set keyboard=ɑ æ ə ɪ ʊ ʌ e ɒ \

 ɑ: ɜ ɜ: ɒ: i: u: ɔ:\

 ŋ ʃ θ ð ʒ ˞ ʧ ʤ\

 eɪ aɪ ɔɪ aʊ əʊ ɪə eə

!!« » € ʉ ø ɐ ʏ ç β

!!ɣ ʎ ɲ ʁ ɥ ʔ

  !goto kb

!endif

!if $keyboard=ipa

  !set keyboard= ɑ ɐ ɒ æ ɓ ʙ β ɔ ɕ ç ɗ ɖ ð ʤ ə ɘ ɚ ɛ ɜ \

ɝ ɞɟ ʄ ɡ ɠ ɢ ɢ ʛ ɦ ɧ ħ ɥ ʜ ɨ ɪ ʝ ɭ ɬ ɫ ɮ ʟ\

ɱ ɯ ɰ ŋ ɳ ɲ ɴ ø ɵ ɸ θ œ ɶ ʘ ɹ ɺ ɾ ɻ ʀ ʁ ɽ\

ʂ ʃ ʈ ʧ ʉ ʋ ʊ ʌ ɣ ɤ ʍ χ ʎ ʏ ʑ ʐ ʒ\

ʔ ʡ ʕ ʢ ǀ ǁ ǂ ǃ

  !goto kb

!endif

!if $keyboard=fr_ipa

  !set keyboard= i e ɛ a ɑ ɔ o u y ø  œ ə \

ɛ̃ ɑ̃ ɔ̃ j w ɥ [ ]\

p b t d k g v f\

s z ʃ ʒ l m n ɲ ʀ      \

  !! ɳ

  !goto kb

!endif

!if $keyboard=braille

  !set prefix=10

  !set keyboard=ñ ó ù ĉ ā û ċ ă ú Ċ \

õ ÷ ý č ą ÿ ď ć þ Ď ĕ \

ė Ī ĝ ĭ ĥ Ĭñ Ĭó Ĭù Ĭĉ Ĭā Ĭû Ĭċ \

Ĭă Ĭú ĬĊ Ħ Ħ ò Ć ü Ĕ \

Ģ Ė ö Ė ô Ģ Ģ

  !goto kb

!endif

:kb

!set keyboard=!declosing $keyboard

!set keyboard=!rows2lines $keyboard

!set keyboard=!lines2rows $keyboard

!set keyboard=!singlespace $keyboard

!set keyboard=!rows2lines $keyboard

!if $prefix!=

  !set keyboard=!replace internal # by #$prefix in $keyboard

!endif

!set cnt_kb=!linecnt $keyboard

<script>

/*<![CDATA[*/

var browser="";

var obj=new Object();

!for u = 1 to $cnt_kb

  !set l=!line $u of $keyboard

  !set l=!trim $l

  !set l$u = !items2words $l

!next

!if $cnt_kb= 0

  !set cnt_kb=4

!endif

!for u = 1 to $cnt_kb

  var l$u= "$(l$u)" ;

!next

function checkBrowser()

	{

	if(navigator.appName=='Microsoft Internet Explorer')

		{browser='I';}

	else if(navigator.appName=='Netscape')

		{browser='N';}

	return browser;

	}

function addText(text)

	{

	obj=document.forms['replyform'].elements['reply$i'];

	if(checkBrowser()=="I")

	 {

		var start=obj.selectionStart;

		var beg=obj.value.substring(0, start);

		var end=obj.value.substring(start);

		obj.value=end+text+beg;

		obj.selectionStart=obj.selectionEnd=start+text.length;

		}

	else

		{

		var start=obj.selectionStart;

		var beg=obj.value.substring(0, start);

		var end=obj.value.substring(start);

		obj.value=beg+text+end;

		obj.selectionStart=obj.selectionEnd=start+text.length;

		obj.focus();

		}

	}

function writeChar(win,string)

	{

	var buttons=string.split(' ');

	var i;

	for(i=0;i<buttons.length;i++)

		{

		document.write('<input style="{$style}" type="button" value="'+buttons[i]+'" id="'+buttons[i]+'" onclick="addText(\''+buttons[i]+'\');">');

		}

	}

/*]]>*/

</script>

<div class="wimscenter">

<script>

/*<![CDATA[*/

!for a = 1 to $cnt_kb

  writeChar(self,l$a);

  document.write('<br>');

!next

/*]]>*/

</script>

</div>

:universal

<div class="wimscenter">

<textarea name="reply$i" rows="$sizev" cols="$sizeh"  $wims_id $inputoption>$(reply$i)</textarea>

</div>

!!data= decodeURIComponent(data);

!if $wims_read_parm!=noprompt

 </td></tr>

!endif

!reset inputsize