Subversion Repositories wimsdev

!set lang_exists=yes

!default wims_name_passsup=$wims_name_Password ($name_sup)
!default wims_name_password=$wims_name_Password ($name_classesss)
!default wims_name_institution=$name_Name_portal
!default wims_name_description=$wims_name_name $name_classesss

!set cname=!item $cltype+1 of une classe virtuelle,,un groupement de classe,,\
  un portail d'établissement

!if noagreecgu iswordof $error
  $noagreecgu_msg
  !exit
!endif

!if no_subclass iswordof $error
  Vous n'avez pas le droit de créer des sous-classes dans la situation
  actuelle.
  !set restart=no
  !exit
!endif

!if no_right iswordof $error
  Désolé, vous n'avez pas le droit de créer des classes virtuelles sur ce site.
  Veuillez
  !mailurl $wims_site_manager contacter le gestionnaire du site\
Création de classe virtuelle
  pour plus de détails.
  !set restart=no
  !exit
!endif

!if not_manager iswordof $error
  Désolé, seul le gestionnaire du site a le droit de créer $cname.
  !exit
!endif

!if getpass iswordof $error
  !if $sendmail!=$empty
    Le mot de passe a été envoyé à l'adresse électronique $sendmail.
    <br class="spacer">
  !endif
  !if $regpass!=$empty
    <div class="wims_msg warning">
      Désolé, votre mot de passe n'est pas correct. Veuillez réessayer.
    </div>
  !else
    !if $sendmail=$empty
      La création d'$cname sur ce site est protégée par un mot de passe.
    !endif
  !endif
  !form reply
  <input type="hidden" name="step" value="$step">
  <input type="hidden" name="job" value="$job">
  <label for="regpass">
    Entrez le mot de passe&nbsp;:
  </label>
  <input size="16" name="regpass" type="password" id="regpass" required>
  <input type="submit" value="$wims_name_send">
  !formend
  </div>
  <div class="wims_msg info">
    Le mot de passe nécessaire à la création de classes virtuelles
    peut être obtenu auprès du
    !mailurl $wims_site_manager gestionnaire\
Mot de passe pour la création de classes virtuelles
    de ce site WIMS.
    !if $regpassmail!=$empty and $sendmail=$empty
      !form reply
        Si vous disposez d'une adresse électronique dont le domaine est reconnu par le serveur,
        vous pouvez également recevoir le mot de passe par message électronique
        en saisissant <label for="adresse1">votre adresse électronique </label> ci-contre :
        <div class="wimscenter">
          <input type="text" id="adresse1" name="adresse1" value="$adresse1" size="20">
          <input type="hidden" name="step" value="0">
          !let nbaddr=!itemcnt $regpassmail
          !if $nbaddr=1
            @$regpassmail
            <input type="hidden" name="adresse2" value="$regpassmail">
          !else
            @
            !formselect adresse2 list $regpassmail
          !endif
          <input type="submit" value="$wims_name_send">
        </div>
      !formend
    !else
      !reset sendmail
    !endif
  </div>
  !set restart=no
  !exit
!endif

!if getid iswordof $error
  !if $regpass$regid!=$empty
    Désolé, votre mot de passe n'est pas correct. Veuillez réessayer.
  !else
    La création de classes virtuelles sur ce site est protégée par un système
    d'authentification. Veuillez vous identifier.
  !endif
  </div>
  !form reply
    <fieldset class="property_fields halfwidth blockcenter">
      <div class="field box">
        <label for="regid">
          Entrez le nom de votre compte :
        </label>
        <input size="20" name="regid" id="regid" required>
      </div>
      <div class="field box">
        <label for="regpass">
          Et le mot de passe :
        </label>
        <input size="16" name="regpass" id="regpass" type="password"  required>
      </div>
      <div class="wimscenter">
        <input type="submit" value="$wims_name_send">
      </div>
    </fieldset>
  !formend

  <p>
    Remarque. Veuillez écrire au
    !mailurl $wims_site_manager gestionnaire\
Mot de passe pour la création de classes virtuelles
    de ce site si vous voulez un compte de création de classes virtuelles.
  </p>
  !set restart=no
  !exit
!endif

!if class_quota=$error
  Vous avez le droit d'installer jusqu'à $r_quota1 classes. Vous avez fait le
  plein&nbsp;; vous ne pouvez plus en ajouter d'autres.
  !set restart=no
  !exit
!endif

!if bad_secure=$error
  Votre poste actuel ne fait pas partie de la définition
  d'accès sécurisé (<span class="tt wims_code_words">$secure</span>)&nbsp;! C'est probablement une erreur qui
  aurait la conséquence de vous interdire l'accès de contrôle de votre classe.
  <p>
  Lisez attentivement la documentation ci-dessous. Vous pouvez aussi
  laisser ce champ vide (ou mettez un espace) : des codes secrets
  temporaires vous seront envoyés à chaque opération sensible. Vous pouvez aussi
  pour désactiver cette mesure de sécurité en mettant le mot <span class="tt wims_code_words">all</span>.
  </p><hr>
  !read help/hosts.phtml
  !reset secure
  !exit
!endif

!if has_empty=$error
  Vous n'avez pas donné toutes les informations nécessaires pour la création
  d'une classe. Veuillez compléter vos données avant de les soumettre.<br>
  <span class="tt wims_code_words">$(wims_name_$error_subject) requis.</span>
  !exit
!endif

!if too_short=$error
  Le champ de données <span class="tt wims_code_words">$(wims_name_$(error_subject))</span> semble être trop court.
  !exit
!endif

!if bad_date=$error
  Votre date d'expiration n'est pas correcte.
  !exit
!endif

!if anti_date=$error
  Votre classe a une date d'expiration antérieure à aujourd'hui. Elle serait donc
  périmée avant d'être créée!
  !exit
!endif

!if bad_level=$error
  Mauvaise valeur de niveau.
  !exit
!endif

!if bad_email=$error
  Votre adresse électronique n'est visiblement pas valable.
  <p>
  La création de classe ne peut réussir que si vous
    soumettez VOTRE VRAIE adresse électronique.
  </p>
  !exit
!endif

!if existing=$error
  La classe $classname semble déjà exister. Vous ne pouvez pas recréer la
  même classe.
  !exit
!endif

!if pass_discord isin $error
  Le mot de passe (
  !if sup isin $error
    enseignant
    !if class isin $error
      et classe
    !endif
  !else
    !if class isin $error
      classe
    !endif
  !endif
  ) que vous avez retapé ne correspond pas au premier. Votre
  création de classe n'est donc pas pris en compte&nbsp;; vous pouvez réessayer encore
  une fois.
  !exit
!endif

!if bad_pass=$error
  Le <strong>$(wims_name_$(error_subject))</strong> que vous avez choisi
  contient des caractères illégaux.<br>
  Veuillez utiliser un mot contenant uniquement des chiffres ou des lettres
  sans accent et sans espace entre eux.
  !exit
!endif

!if bad_code=$error
  Vous n'avez pas entré le bon code pour la classe. L'adresse électronique
  que vous avez fournie est-elle correcte&nbsp;?
  <p>
  Nous avons enregistré cet échec.
  </p>
  !exit
!endif

!if define_fail=$error or abuse=$error
  Le serveur n'a pas réussi à insérer votre classe dans la base de
  données. C'est une erreur interne du logiciel.
  <p>
    Veuillez rapporter le problème au
    !mailurl $wims_site_manager gestionnaire de ce site\
user registration failure
. Merci&nbsp;!
  </p>
  !exit
!endif

!if duplicate=$error
  Vous avez tenté de recréer une classe déjà créée. Peut-être
  avez-vous cliqué sur le bouton <span class="tt">actualiser</span>&nbsp;? En tout cas, votre classe
  $classname est déjà en place et la deuxième tentative de création
  est ignorée.
  <div>
  !read adm/lang/links.phtml.$modu_lang
  </div>
  !exit
!endif

!if classdontexists=$error
  Cette classe n'existe pas.
  !exit
!endif

!if notexempleclass=$error
  Cette classe n'est pas une classe d'exemple : impossible de la copier.
  !exit
!endif

!if badcpmethod=$error
  Méthode de copie impossible à identifier. Recommencer l'opération. Si l'erreur persiste contacter l'administrateur du serveur.
  !exit
!endif

!if cloningnotallow=$error
  La duplication de cette classe n'est pas autorisée par son administrateur.
  !exit
!endif

!if badcloningpwd=$error
  Mauvais mot de passe de duplication.
  !exit
!endif

!if disallowcloning=$error
  Aucune duplication de cette classe ne peut être réalisée.
  !exit
!endif

!if subclasslimit=$error
  Vous avez atteint le nombre maximum de sous-classes ($max_subclasses). Il n'est pas possible d'en créer d'autres.
  !exit
!endif

!if bad_file iswordof $error
  Désolé mais je ne peux pas reconnaître <em>$wims_deposit</em>
  comme un fichier de sauvegarde d'une classe. Soit vous avez envoyé un mauvais
  fichier, soit le fichier est endommagé.
  !exit
!endif

!msg $error