Subversion Repositories wimsdev

!! job=wiewpage
!! supervisor can view page of participant connected to the tchat
!!

!! -------- user check
!bound user within $ulist default $empty
!if $user=$empty
  error=nouser
  !exit
!endif

!! -------- check if authorized session
list_window=!defof $user in wimshome/s2/$wims_session/.indexusersession
nbwindow=!itemcnt $list_window
!if $numberses<1 or $numberses>$nbwindow
  error=usernotintchat
  !exit
!endif
userses=!item $numberses of $list_window
test=!fileexists wimshome/s2/$userses/last.html
!if tchat isin $userses or $test!=yes
  error=addressplay
  !exit
!endif

po=!positionof item $user in $ulist
username=$(nlist[$po])
name_title=$username $name_page $numberses

!!basesession=!replace internal _ by , in $userses
!!basesession=!item 1 of $basesession
!!basesession=!nospace $basesession

!! ---------- make list of file of the user
!! the file of list_forbiddent are ignored (to be completed if need)
list_forbidden=last.html
listfile=!sh cd $wims_home/s2/$userses;\
ls *
listfile=!lines2items $listfile
listfile=!listcomplement $list_forbidden in $listfile
listsed=$empty
listlink=$empty
!for f in $listfile
  listsed=!append line s#$f#user$po-$f#g; to $listsed
  listlink=!append line ln -s $wims_home/s2/$userses/$f $wims_home/s2/$wims_session/user$po-$f; to $listlink
!next f
!! ---------- build copy of user page
!read oef/fr/names

page_content=!sh sed '1,3d' $wims_home/s2/$userses/last.html | sed 's#$(userses)#$wims_session#gi;\
s#<a href="[^"]*"#<a href=""#gi;\
s# target="[^"]*"# #gi;\
s#<input type="submit"#<input type="submit" disabled #gi;\
s#<input type="image"#<img #gi;\
s#<button #<button disabled #gi;\
s#onclick="wims_[a-zA-Z0-9^=]*=window.open([^)]*)"# #gi;\
$listsed'

!! make link to file of the user_session in supervisor_session (del old link before)
list=!sh cd $wims_home/s2/$wims_session;\
lt=`find user$(po)* -type l 2>/dev/null`;\
for f in $$lt; do rm $$f; done;\
$listlink

warning=workinprogress

!! --- suppress auto refresh (need to put a button to refresh)
!let rd=!randint 111111,999999
!!local_html_header=<META HTTP-EQUIV="Refresh" CONTENT="$(tchat_refreshtiming);wims.cgi?session=$wims_session&+cmd=reply&+module=adm/class/tchat&+job=viewpage&+numberses=$k&+user=$user">
!set wims_menu_items=!append line refresh,1,module=$module&cmd=reply&+module=adm/class/tchat&+job=viewpage&+numberses=$k&+user=$user&+serial=$rd to $wims_menu_items