Subversion Repositories wimsdev

!!INDEX
!let module_author      =XIAO, Gang
!let module_address     =xiao@unice.fr
!let module_title       =Définir vos préférences pour WIMS
!let module_description =définir préférences pour wims
!let module_version     =1.00
!let module_wims_version=0.13
!let module_language    =fr
!let module_copyright   =&copy; 1998 (<a href=COPYING>GNU GPL</a>)
!let module_category    =adm
!let module_level       =
!let module_domain      =adm
!let module_keywords    =wims
!!INDEXEND

!let texsize=!char 1 of $useropts
!let texalign=!char 2 of $useropts
!default texsize=$[$wims_texbasesize-1]
!default texalign=$talign
!let useropt2=!char 3 to -1 of $useropts
!if $useropts!=$empty and $wims_realuser!=$empty
 !readproc adm/class/userdef classes,$wims_class,$wims_realuser
 !setdef !set user_opts=$useropts in $userdef
 !setdef wims_useropts=$useropts in wimshome/$wims_sesdir/var.stat
!endif

!header

Cette page a pour but de vous permettre de changer vos préférences pour vos
séances de travail sur WIMS.
<p>
Les préférences contiennent actuellement :
<ul>
!if $wims_user=$empty
 <p><li>La langue par défaut.
  !for l=1 to $wims_language_cnt
   !let la=!word $l of $wims_site_languages
   !href cmd=resume&phtml=useropts.phtml.$la&lang=$la <img src=gifs/$la.gif border=1>$(lang_name_$la)
   &nbsp;&nbsp;
  !next l
!endif
 <p><li>La taille des symboles et formules mathématiques. Utiliser la ligne suivante
  pour comparer les tailles des symboles et des textes.
  <p>
  Lettres greques $m_alpha,$m_pi. Expression mathématique
  !let ins_align=middle
  !instex $$x^3\sin(x)+{\sqrt{x^2+1}\over 107}-123.45$$.
  Une inégalité mixte
  <center>| $m_a + $m_b | $m_le $m_varepsilon + 123.45.</center>
  <p>
  Vous pouvez
  !let ts1=!eval $texsize-1
  !let ts2=!eval $texsize+1
  !if $ts1<1
    !let ts1=1
  !endif
  !if $ts2>9
    !let ts2=9
  !endif
  !href cmd=resume&useropts=$ts1$texalign$useropt2 diminuer
  ou
  !href cmd=resume&useropts=$ts2$texalign$useropt2 augmenter
  la taille des symboles mathématiques, pour les faire correspondre à celle
  du texte.
  Si l'expression
  !insmath (x+y)/(x^2+y^2)
  est
  !if $texalign=1
   trop haute par rapport &agrave; la ligne de texte,
   !href cmd=resume&useropts=$(texsize)0$useropt2 cliquez ici
   pour la faire descendre.
  !else
   trop basse par rapport &agrave; la ligne de texte,
   !href cmd=resume&useropts=$(texsize)1$useropt2 cliquez ici
   pour la faire monter.
  !endif

</ul>

!if $wims_user=$empty
 Quand tout correspond exactement à ce que vous désirez, mettez
 <a href="$wims_ref_name?lang=$lang&useropts=$texsize$texalign$useropt2"
 title="WIMS">ce lien</a>
 dans votre bookmark, pour conserver ces préférences pour vos connections
 ultérieures.
!else
 Vos préférences seront préservées dans vos futures connections dans cette
 classe.
!endif

<p>

:end
!tail