Subversion Repositories wimsdev

!!INDEX
!let module_translator=
!let module_translator_address=
!let module_title=Setup your preferences for WIMS
!let module_description=define preferences for wims
!let module_language=en
!!INDEXEND

!set tip=Firefox/Safari natively manages Mathml without extension.\
  For all other browsers, WIMS will automatically load the Mathjax library\
  to display mathematical formulas. If you encounter a problem with Mathjax,\
  we invite you to try Firefox which natively manages Mathml and to share it with us.

!read proc/useropts.proc

!header

<p>This page lets you configure some preferences on WIMS

<div id="widget_useropts">
  <ul>
    <li><a href="#formula">Mathematical formulas</a></li>
    !if $wims_user=$empty
      <li><a href="#language_selector">Default language</a></li>
    !endif
    <li><a href="#accessibility">Accessibility</a></li>
  </ul>

  !if $wims_user=$empty
    <div id="language_selector">
      <h2>Default language</h2>
      <p>
        Choose site language :
        !read themes/_widgets/language_selector.phtml
      </p>
    </div>
  !endif

  <div id="formula">
    <h2>Mathematical formulas</h2>
    <p>
      You can choose beetween 2 display modes: image mode or  MathML.
    </p>
    !if $texalign=2
      <p>The server is currently set to MathML if you have a suitable browser.</p>
    !endif
    Some display test:
    <ul>
      <li>
        Greek letters:
        <pre>
          !insmath alpha != pi
        </pre>
      </li>
      <li>
        Mathematical expression
        !let ins_align=middle
        !! we need to force dynamic insertion
        !set pw=2
        <pre>
          !insmath x_{1,2} = \frac{-b \pm \sqrt{b^{$pw} - 4a c}}{2a}
        </pre>
      </li>
      <li>
        A mixed inequality:
        <pre>
          !insmath | a + b | <= epsilon + 123.45
        </pre>
      </li>
    </ul>

    !if $texalign=2
      <p>
        If the formula is not correctly displayed, you can use another
        browser or use the serveur with "math with images".
      </p>
      <h3>Mode d'affichage</h3>
      <p>
        You currently use MathML
        !set wims_ref_class=wims_button
        !href cmd=resume&useropts=$(arg)0$font Passer au mode image
      </p>
      <h3 id="formula_options">Option du mode MathML :</h3>
      <p>Le mode MathML permet un zoom sur les formules par un click de souris.</p>
      !set wims_ref_class=wims_button
      !if $useropts!=$texsize$(texalign)1$font
        Le zoom est <span class="disabled">désactivé</span>.
        !href cmd=resume&useropts=$texsize$(texalign)1$font#formula_options activer
        <span class="wims_button disabled">désactiver</span>
      !else
        Le zoom est <span class="oef_indgood success">activé</span>.
        <span class="wims_button disabled">activer</span>
        !href cmd=resume&useropts=$texsize$(texalign)0$font#formula_options désactiver
      !endif

      <h3>Navigateurs compatibles MathML</h3>
      $tip
    !else
      <p>
        Actuellement, vous utilisez le serveur en <strong>mode image</strong>.<br>
        Avec un navigateur compatible, vous pouvez utiliser le mode MathML.
      </p>
      <h3>Mode d'affichage</h3>
      <p>
        Vous êtes en mode Image
        !set arg=!nospace $texsize 2
        !set wims_ref_class=wims_button
        !href cmd=resume&useropts=$(arg)0$font Passer au mode MathML
      </p>
      <h3>Options du mode image</h3>
      <ul><li>
        Size of mathematical symbols and formulas.
        !let ts1=!eval $texsize-1
        !let ts2=!eval $texsize+1
        !if $ts1<1
          !let ts1=1
        !endif
        !if $ts2>9
          !let ts2=9
        !endif
        !set wims_ref_class=wims_button
        !href cmd=resume&useropts=$ts1$texalign$zoom$font#formula <img src="gifs/doc/dgauche.gif" style="width:1em">
        !set wims_ref_class=wims_button
        !href cmd=resume&useropts=$[$wims_texbasesize-1]$texalign$zoom$font#formula Normal
        !set wims_ref_class=wims_button
        !href cmd=resume&useropts=$ts2$texalign$zoom$font#formula <img src="gifs/doc/ddroite.gif" style="width:1em">
      </li><li>
        Position of the formulas. If the expression
        !insmath (x+y)/(x^$pw + y^2)
        is
        !if $texalign=1
          too high with respect to the text line,
          !set wims_ref_class=wims_button
          !href cmd=resume&useropts=$(texsize)0$zoom$font click here to lower it.
        !else
          too low with respect to the text line,
          !set wims_ref_class=wims_button
          !href cmd=resume&useropts=$(texsize)1$zoom$font click here to raise it.
        !endif
      </li></ul>
    !endif
  </div>

  <div id="accessibility">
    <h2>Accessibility</h2>

    <p>You can modify space width beetween characters.
      !if $useropts=$(texsize)$texalign$(zoom)1
        !set secondary1=wims_button disabled
        !set secondary2=wims_button
      !else
        !set secondary2=wims_button disabled
        !set secondary1=wims_button
      !endif
      !set wims_ref_class=$secondary2
      !href cmd=resume&useropts=$(texsize)$texalign$(zoom)0 Normal

      !set wims_ref_class=$secondary1
      !href cmd=resume&useropts=$(texsize)$texalign$(zoom)1 Mode espacé
    </p>
    <p>The spaced mode may be better if you have some reading difficulties.</p>
  </div>
</div>
!if $jquery_defined=yes
  !read adm/tabscript useropts
!endif

<p class="spacer">
  !if $wims_user=$empty
    When everything corresponds exactly to what you want, put
    !set wims_ref_class=wims_button
    <a href="$wims_ref_name?lang=$lang&+useropts=$texsize$texalign$zoom$font" title="WIMS">
      this link</a>
     into your bookmark, to keep these preferences for your future connections.
  !else
    Your preferences will be preserved in your future logins in this class.
  !endif
</p>

!tail