Subversion Repositories wimsdev

# DelExam (BETA)
# Suppression de l'examen qexam

### Attention : il faut etre sur que la suppression ne cause pas de décalage dans les notes, a verifier !!

#Pour commencer, on verifie la classe
!read scripts/check.class
!if $error!=$empty
 !exit
!endif

type=exams
!read scripts/check.proc
!if $error!=$empty
 !exit
!endif

state=!line 1 of $qproperties

#ici on verifie que l'examen est "En préparation"
#STATUS FORMAT :
#0 = EN PREPARATION
#1 = ACTIF
#2 = EXPIRE (PERIME)
#3 = CACHE (PERIME+cache)

!if $state!=0
 error=Exam #$qexam has been activated.
 !exit
!endif

# Il faut également vérifier qu'aucun des exams > $qexam n'a pas été activé

!for n=$[$qexam+1] to $cnt
  q_properties=!record $n of $listfile
  state=!line 1 of $q_properties
  !if $state!=0
    error=This Exam can't be deleted : A more recent exam (#$n) has been activated.
    !exit
  !endif
!next n

dir=$wims_home/log/classes/$qclass

!sh cd $dir\
rm .E$qexam\
cd $type\
rm .exam$qexam


n=$[$qexam+1]

!while $n <= $cnt
 !sh mv $dir/$type/.exam$n $dir/$type/.exam$[$n-1]
 !sh mv $dir/.E$n $dir/.E$[$n-1]
 !increase n
!endwhile

# Les fichiers sont supprimés, reste à corriger le contenu du fichier d'index .exams

update_field=0
!read scripts/update.proc