Subversion Repositories wimsdev

!read tabletheme
!if $data=$empty
  parent=!replace internal $wims_subsession by $empty in $wims_session
  !! get data of exercise and user (first time)
  !for n in author,email,module
    tmp=!getdef w_$n in wimshome/sessions/$parent/var
    data=!append line $n=$tmp to $data
    local_$n=$tmp
  !next n
  !for n in wims_seed,exo
    tmp=!getdef w_$n in wimshome/sessions/$parent/var
    data=!append line $n=$tmp to $data
  !next n
  tmpfile=!nospace wimshome/public_html/modules/$local_module/INDEX
  !for n in author,version
    tmp=!getdef $n in $tmpfile
    data=!append line module_$n=$tmp to $data
  !next n
  maintainer_address=!getdef maintainer_address in $tmpfile
  address=!getdef address in $tmpfile
  data=$data\
module_maintainer_address=$maintainer_address\
module_address=$address\
Server=$httpd_HTTP_HOST\
Server version=$wims_version\
\
Sender:$wims_firstname $wims_lastname\
Mail:$wims_email\
$wims_now

!endif

!if $save!=$empty
  !if $source!=$empty
    source=!char 1 to 1000 of $source
    listaddr=$wims_email,$local_email,$address,$maintainer_address
    !!qualite@wimsedu.info
    listaddr=!nonempty item $listaddr
    listaddr=!listuniq $listaddr
    listaddr=!items2words $listaddr
    !mailto $listaddr\
[WIMS] $name_titlemail\
<h1>$name_mailcomment</h1>\
<p>$source</p>\
<h1>$name_mailinfogene</h1>\
<pre>$data</pre>
    success=confirm
  !else
    error=no_comment
  !endif
!endif

!reset save