Subversion Repositories wimsdev

!set methtit2=Multiplicar una ecuación por un número distinto de cero
!set methtit=Multiplicar una ecuación por un número
!set methenv=ZZ QQ RR CC
!set methparmtype=number,parm equation
!set methhelp=Este método transforma una ecuación \(A = B)\
  en la ecuación equivalente \(A*n = B*n), donde \(n) es un número,\
  que debe ser distinto de cero para garantizar la equivalencia entre la ecuación\
  de partida y la transformada.

!if $wims_read_parm iswordof form check
  !goto $wims_read_parm
!endif

!exit
:form
Multiplicar la ecuación
!read deduc/methparm.phtml 2
$ por el número
!read deduc/methparm.phtml 1,10

!exit
:check
!distribute items $methparmobj2 into data,left,sign,right
!if $methparm1=0
  error=Multiplicar una ecuación por 0 le hace perder información, y \
    por lo tanto, está prohibido.
  !advance penalty
  !exit
!endif
methexp=Multiplier \($left $sign $right) par \($methparm1)

!read deduc/sub/simplify ($left) * ($methparm1)\
        ($right) * ($methparm1)
!distribute lines $out into newleft,newright
!if $newleft=$empty or $newright=$empty
  error=bad_data
  !exit
!endif
newsign=$sign
newobject2=$newleft $newsign $newright
oldobject=2

contextlist=$ct_Onlywhen se multiplica por un número distinto de cero,\
        $ct_Onlywhen se multiplica por un número positivo,\
        $ct_Onlywhen ambos lados son positivos,\
        $ct_Onlywhen ambos lados tienen el mismo signo

!exit