Subversion Repositories wimsdev

!set methtit=Ajouter deux inégalités
!set methenv=ZZ QQ RR
!set methparmtype=parm inequality >,parm inequality >
!set methhelp=Cette méthode applique la propriété suivante sur deux\
inégalités existantes, pour en déduire une troisième :\
 <div class="wimscenter">\
 Si \(a > b) et \(c > b), alors \(a+c > b+d) .\
</div>\
 Cette dernière inégalité sera mise dans les hypothèses.

!if $wims_read_parm iswordof form check
 !goto $wims_read_parm
!endif

!exit
:form
 Additionner les inégalités
 !read deduc/methparm.phtml 1
 et
 !read deduc/methparm.phtml 2

!exit
:check
 !distribute items $methparmobj1 into data,left1,sign1,right1
 !distribute items $methparmobj2 into data,left2,sign2,right2
 methexp=Ajouter \($left1 $sign1 $right1) et \($left2 $sign2 $right2)
 
 gt=>
 lt=<
 !if ($gt isin $sign1 and $lt isin $sign2) or\
        ($lt isin $sign1 and $gt isin $sign2)
  !exchange left2,right2
 !endif
 !read deduc/sub/simplify $left1 + ($left2)\
        $right1 + ($right2)
 !distribute lines $out into newleft, newright
 !if $newleft=$empty or $newright=$empty
  error=bad_data
  !exit
 !endif

 !if $gt isin $sign1
  s_=>
 !else
  s_=<
 !endif
 eq=$empty=
 !if $eq isin $sign1 and $eq isin $sign2
  s_=$s_=
 !endif
 newobject0=$newleft $s_ $newright
 oldobject=0

 contextlist=$ct_Always,\
        $ct_Onlywhen les deux inégalités sont positives,\
        $ct_Onlywhen l'une des deux inégalités est positive,\
        $ct_Onlywhen l'une des deux inégalités est de même signe

!exit